Автор: xls Вторник, 07 Марта 2006, 22:02
У меня на работе две сети. В одной из них ip должен определяеться автоматически. После этого все предыдущие настройки (второй сети) сбиваются.
Слышал есть такая прога которая сохраняет настройки нескольких сетей и даёт возможность быстрого переключения между ними. Может подскажете название прожки, а ещё лучше скажете где взять? Заранее спасибо.
Автор: yozh Среда, 08 Марта 2006, 1:44
Как вариант: cmd-скрипты, использующие netsh. Запустил нужный скрипт - все сетевые настройки стали какие надо. Если интересно, могу завтра кинуть пример.
Автор: xls Четверг, 09 Марта 2006, 21:34
yozh, буду очень признателен
Автор: yozh Четверг, 09 Марта 2006, 23:49
Завтра. Теперь - только завтра
Автор: Levon Пятница, 10 Марта 2006, 8:26
А стандартные сетевые настройки не пашут .. .? Если установть "Получать IP адресс автоматически" появляется новая закладка .... "Альтернативные настройки" ... пробовал ... ?
Автор: yozh Пятница, 10 Марта 2006, 12:30
Вот пример скрипта, задающего статический IP, шлюз (GATEWAY), DNS и WINS (ненужное - просто убрать или закомментировать при помощи rem). Вместо x.x.x.x подставить реальные адреса, сохранить всё в файл с расширением cmd и запускать при необходимости. Я это использую на ноутбуке, потому что он бывает в разных сетях с разными настройками. Что касается IFACE: посмотри, как у тебя называется сетевой интерфейс (тем же ipconfig) и подставь своё.
Код
@echo off
set IFACE="LAN-Verbindung"
set IP=x.x.x.x
set MASK=x.x.x.x
set GATEWAY=x.x.x.x
set GWMETRIC=1
set DNS1=x.x.x.x
set DNS2=x.x.x.x
set WINS1=x.x.x.x
set WINS2=x.x.x.x
echo Setting the IP, Mask, Gateway and Metric:
netsh interface ip set address name=%IFACE% source=static addr=%IP% mask=%MASK% gateway=%GATEWAY% gwmetric=%GWMETRIC%
echo Specifying the primary DNS-server address:
netsh interface ip set dns name=%IFACE% source=static addr=%DNS1% register=PRIMARY
echo Adding the secondary DNS-server address:
netsh interface ip add dns name=%IFACE% addr=%DNS2% index=2
echo Specifying the primary WINS-server address:
netsh interface ip set wins name=%IFACE% source=static addr=%WINS1%
echo Adding the secondary WINS-server address:
netsh interface ip add wins name=%IFACE% addr=%WINS2% index=2
rem Pause, 4 seconds:
ping -n 4 -w 1000 127.0.0.1>nul
echo The current network settings:
ipconfig /all
rem netsh interface ip dump
pause
А вот этот пример включает DHCP-вариант настроек:
Код
@echo off
set IFACE="LAN-Verbindung"
echo Deleting all WINS-servers:
netsh interface ip delete wins name=%IFACE% all
echo Deleting all DNS-servers:
netsh interface ip delete dns name=%IFACE% all
echo Setting the DHCP:
netsh interface ip set address name=%IFACE% source=dhcp
rem Pause, 4 seconds:
ping -n 4 -w 1000 127.0.0.1>nul
echo The current network settings:
ipconfig /all
rem netsh interface ip dump
pause
Автор: xls Суббота, 11 Марта 2006, 12:04
Огромное спасибо! Всё отлично работает! Пробовал прогу NetSwitcher но она требует установки NET Framework
А тут просто и гениально! Буду пользоваться этим. Огромное спасибо за помощь!
Автор: yozh Суббота, 11 Марта 2006, 13:13
Цитата
Пробовал прогу NetSwitcher но она требует установки NET Framework
me смеялся. Они бы ещё на java её написали
.
Цитата
А тут просто и гениально!
Скрипты вообще позволяют сильно упростить жизнь. Особенно - для Windows Scripting Host (WSH).
Цитата
Буду пользоваться этим. Огромное спасибо за помощь!
В Win9x/ME скрипт работать не будет. а) Там нет netsh; б) Эти системы ещё не умеют менять IP без перезагрузки. Там я делал inf/reg-файл, который писал параметры непосредственно в реестр. Потом - перезагрузка...